CFT and gravity, solutions week 5

Casimir operator

We check that the Casimir operator commutes with the conformal algebra.

Specify the axioms and commutation relations

comrelations={
Dot[a1___,x_ a2_,a3___]:>x Dot[a1,a2,a3]/;And@@(FreeQ[x,#]&/@{M,Di,Ks,P}),
Dot[a1__,x_ ,a3___]:>x Dot[a1,a3]/;And@@(FreeQ[x,#]&/@{M,Di,Ks,P}),
Dot[a1___,x_ ,a3__]:>x Dot[a1,a3]/;And@@(FreeQ[x,#]&/@{M,Di,Ks,P}),
Dot[a1___,a2_+a3_,a4___]:>Dot[a1,a2,a4]+Dot[a1,a3,a4],
Dot[a1__,1,a4___]:>Dot[a1,a4],
Dot[a1___,1,a4__]:>Dot[a1,a4],
Dot[a1__,0,a4___]:>0,
Dot[a1___,0,a4__]:>0,
M[a_,a_]:>0,
M[a_,b_]:>-M[b,a]/;!OrderedQ[{a,b}],M[a_,b_].M[c_,d_]:>M[c,d].M[a,b]+I(δ[a,c]M[b,d]-δ[b,c]M[a,d]-δ[a,d]M[b,c]+δ[b,d]M[a,c])/;!OrderedQ[{{a,b},{c,d}}],
M[a_,b_].Di:>Di.M[a,b],
M[a_,b_].Ks[c_]:>Ks[c].M[a,b]+I(δ[a,c]Ks[b]-δ[b,c]Ks[a]),
M[a_,b_].P[c_]:>P[c].M[a,b]+I(δ[a,c]P[b]-δ[b,c]P[a]),
Di.Ks[a_]:>Ks[a].Di-Ks[a],
Di.P[a_]:>P[a].Di+P[a],
Ks[a_].Ks[b_]:>Ks[b].Ks[a]/;!OrderedQ[{a,b}],
Ks[a_].P[b_]:>P[b].Ks[a]+2δ[a,b]Di-2I M[a,b],
P[a_].P[b_]:>P[b].P[a]/;!OrderedQ[{a,b}]};

We only need a simple contraction rule:

Attributes[δ]=Orderless;
dot= {δ[μ_,ν_]Dot[c___,z_[a___,ν_],d___]:>Dot[c,z[a,μ],d],δ[μ_,ν_]Dot[c___,z_[ν_,a___],d___]:>Dot[c,z[μ,a],d],δ[μ_,ν_]z_[a___,ν_]:>z[a,μ],δ[μ_,ν_]z_[ν_,a___]:>z[μ,a],δ[μ_,α_]δ[α_,ν_]:> δ[μ,ν] ,((δ[μ_,ν_])^2):>d,δ[μ_,μ_]:>d};

Compute commutators of Casimir and generators

Cas=Di.Di-(1/2)(Ks[a].P[a]+P[b].Ks[b])+(1/2)M[a,b].M[a,b];

(Cas.Ks[c]-Ks[c].Cas//.comrelations//Expand)//.dot
%/.{Ks[a_].M[a_,b_]->Ks[zz]M[zz,b],Ks[a_].M[b_,a_]->Ks[zz]M[b,zz]}/.comrelations

(Cas.M[c,e]-M[c,e].Cas//.comrelations//Expand)//.dot
(%//.comrelations//Expand)//.dot/.comrelations

Cas.Di-Di.Cas//.comrelations//Expand

(Cas.P[c]-P[c].Cas//.comrelations//Expand)//.dot//.comrelations

Exercise 3: Matching on the lattice

σσ=(1/((((z1-z2)(zb1-zb2)))^(1/8)));

Sum[c[i+1] σ[i][1],{i,0,2}]+c[4](σplus[4][1]+σminus[4][1]);
Sum[c[i+1] σ[i][2],{i,0,2}]+c[4](σplus[4][2]+σminus[4][2]);
% %%//Expand;
aux1=%/.{σ[i_][1]σ[j_][2]:>D[σσ,{z1,i},{zb1,i},{z2,j},{zb2,j}],σ[i_][1]σplus[4][2]:>D[σσ,{z1,i},{zb1,i},{z2,4}],σ[i_][2]σplus[4][1]:>D[σσ,{z2,i},{zb2,i},{z1,4}],σ[i_][1]σminus[4][2]:>D[σσ,{z1,i},{zb1,i},{zb2,4}],σ[i_][2]σminus[4][1]:>D[σσ,{z2,i},{zb2,i},{zb1,4}],
σplus[4][1]σplus[4][2]:>D[σσ,{z1,4},{z2,4}],
σminus[4][1]σminus[4][2]:>D[σσ,{zb1,4},{zb2,4}],σplus[4][1]σminus[4][2]:>D[σσ,{z1,4},{zb2,4}],σplus[4][2]σminus[4][1]:>D[σσ,{zb1,4},{z2,4}]};

Op[h_,hb_]:=(1/((((z1-z2))^(2h))(((zb1-zb2))^(2 hb))))
aux2=((c[5])^2)(D[Op[(1/16)+3,(1/16)],{z1,1},{z2,1}]+D[Op[(1/16),(1/16)+3],{zb1,1},{zb2,1}])//Simplify

Sfinal is the <SS> correlator on the lattice.

aux1+aux2/.{z1->0,zb1->0,z2->z,zb2->zb};
Sfinal=Collect[%,c[i_],Simplify[#,z<0&&zb<0]&]

Let’s just set all the coefficients to 1 and plot:

Sfinal/.{z->r (E^(I θ)),zb->r (E^(-I θ))}/.c[i_]->1
%/.θ->0//PowerExpand
Show[Plot[%,{r,1,10}],Plot[(1/(r^(1/4))),{r,1,10},PlotStyle->Red]]
%%%//ExpToTrig
Manipulate[Plot[%/.r->r0,{θ,0,π},PlotRange->{-7,7},Ticks->{{0,Pi/4,Pi/2,3Pi/4, Pi},Automatic}],{r0,2,10}]